home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tech Arsenal 1
/
Tech Arsenal (Arsenal Computer).ISO
/
tek-11
/
vs_804.zip
/
MISC.EXE
/
FUNC2NG.PRG
< prev
next >
Wrap
Text File
|
1991-11-04
|
4KB
|
159 lines
* Filename......: Func2Ng.Prg
*
* Author........: Vernon E. Six, Jr.
* 2908 Forest Hollow Lane #2329
* Arlington, Texas 76006
* Ph: (214) 283-3282 - Voice
* Ph: (817) 695-0058 - BBS
*
* Last Update...: Wed 10-02-1991 11:28:17
*
* Notice........: Copyright (c) 1991 by Vernon E. Six, Jr.
* All Rights Reserved World Wide
*
#include "FILEIO.CH"
#include "SETCURS.CH"
#include "SET.CH"
STATIC gn_CurrLine := 0
FUNCTION Func2Ng( pc_FileName )
*****
*
* Create a Norton Guides DAT file
*
* Requires FuncDoc.Dbf
*
* # Field Name Type Len Dec
* --------------------------------
* 1 FUNC_NAME C 10 0
* 2 SHORT C 45 0
* 3 DESC M 10 0
* 4 SYNTAX M 10 0
* 5 PASS M 10 0
* 6 RETURN M 10 0
* 7 NOTES M 10 0
* 8 EXAMPLE M 10 0
* 9 USAGE M 10 0
* 10 SEEALSO M 10 0
*
*****
LOCAL c_FileName
LOCAL n_Handle
LOCAL n_CurrRec := 0
SET(_SET_DELETED,.T.)
VS_InitVern()
VS_NewScrn()
*****
* Make sure he specified a filename
*****
IF PCOUNT() = 0
VS_TELL(3,0,"",PADC("Proper Syntax is: Func2Ng {FileName} [Return]",60),"")
RETURN(NIL)
ENDIF
dbUseArea(,,pc_FileName,"FUNC_DOC")
dbCreateIndex( pc_FileName, "FUNC_NAME", {||FUNC_NAME}, .F. )
dbGoTop()
*****
* Open the .DATE file (since we are going to create it!)
*****
c_FileName = ALLTRIM(pc_FileName)+".DAT"
IF (n_Handle := FCREATE( c_FileName, 0 ) ) = F_ERROR
VS_TELL(3,0,PADC("Unable to create "+c_FileName))
RETURN(NIL)
ELSE
VS_Write(n_Handle)
ENDIF
VS_GrabScr()
VS_Palette(2)
VS_NewScrn()
VS_Wind(8,13,16,66,"","")
SETCURSOR(SC_NONE)
@ 10,15 SAY PADC("Fung2Ng.Exe Wed 10-02-1991 11:51:11",50)
@ 12,15 SAY PADC("Writing Data File!",50)
@ 14,15 SAY REPLICATE("░",50)
DO WHILE .NOT. FUNC_DOC->( EOF() )
IF INKEY(.05) > 0
EXIT
ENDIF
n_CurrRec++
@ 14,15 SAY REPLICATE("█", VS_ScrlBar( n_CurrRec, 50, RECCOUNT() ))
VS_WriteLn( "'" + REPLICATE("=",70) )
VS_WriteLn( "!short: " + FUNC_DOC->FUNC_NAME + SPACE(6) + ;
FUNC_DOC->SHORT )
VS_WriteLn( "^B" + FUNC_DOC->FUNC_NAME + "^B" + SPACE(6) + ;
FUNC_DOC->SHORT )
VS_WriteLn( [] )
gn_CurrLine = 7
WrtFld( "Description:", FUNC_DOC->DESC )
WrtFld( "Syntax: ", FUNC_DOC->SYNTAX )
WrtFld( "Pass: ", FUNC_DOC->PASS )
WrtFld( "Return: ", FUNC_DOC->RETURN )
WrtFld( "Notes: ", FUNC_DOC->NOTES )
WrtFld( "Example: ", FUNC_DOC->EXAMPLE )
WrtFld( "Usage: ", FUNC_DOC->USAGE )
WrtFld( "!Seealso:", FUNC_DOC->SEEALSO )
FUNC_DOC->( dbSkip() )
ENDDO
FCLOSE( n_Handle )
VS_PutScr()
dbCloseAll()
RETURN(NIL)
*** EOF: Func2Ng() **********************************************************
FUNCTION WrtFld( pc_Hdr, pc_Text )
*****
* Prints the specified memo field
*****
LOCAL n_Cntr
IF pc_Hdr <> "!Seealso:"
VS_WriteLn( "^B" + pc_Hdr + "^B" )
VS_WriteLn( [] )
ELSE
VS_Write ( "!Seealso: " )
ENDIF
FOR n_Cntr = 1 TO MLCOUNT(pc_Text,70)
VS_WriteLn( SPACE(2) + MEMOLINE( pc_Text, 70, n_Cntr ) )
NEXT n_Cntr
VS_WriteLn( [] )
RETURN(NIL)
*** EOF: WrtFld() ***********************************************************